Excel ile Yaş Hesaplama - Gün, ay, yıl şeklinde hesaplama

Konusu 'Excel Çalışmaları' forumundadır ve YoRuMSuZ tarafından 28 Kasım 2011 başlatılmıştır.

  1. YoRuMSuZ

    YoRuMSuZ Biz işimize bakalım!

    Katılım:
    7 Haziran 2006
    Mesajlar:
    20.529
    Beğenileri:
    1.018
    Ödül Puanları:
    8.080
    Cinsiyet:
    Bay
    Not: Bu çalışa excel 2000, 2002 ve 2003 versiyonlarında çalışır. Excel 2007 ve 2010 versiyonlarında formüllerde küçük değişiklikler olabilir.

    Excel kullanarak gün, ay ve yıl bazında kolaylıkla yaş hesabı ya da iki tarih arasındaki farkı yine gün, ay, yıl bazında hesaplayabilirsiniz. Aynı zamanda bu çalışmayı ihtiyaçlarınız doğrultusunda iki tarih arasındaki sadece ay, sadece gün veya sadece ay farkını bulmak için de uyarlayarak kullanabilirsiniz.

    Burada yapacağımız küçük örnek ile iki tarih arasındaki gün, ay ve yıl hesaplamasını öğreneceğiz. Hem ayrı ayrı hücrelerde hem de tek bir hücrede bu hesaplamanın nasıl yapıldığını öğrenmek için aşağıdaki adımları yapalım.

    Örnek çalışmamız aşağıdaki resimde gösterildiği gibi olacaktır. Bu resim üzerinden anlatım yapıyorum

    [​IMG]

    A2 hücresine doğum tarihini (Örneğin 10.10.1990) şeklinde girelim. B2 hücresine de bugünün tarihini girelim. (üstteki resmi inceleyin)

    B2 hücresinde bugünün tarihini güncel tutmak için =BUGÜN() formülünü girebilirsiniz.

    Yukarıdaki resimde görüldüğü gibi küçük bir tablo hazırladığınızı varsayarak işlemlere devam ediyoruz. Bu uygulamaya göre C2 hücresinde geçen yıl, D2 hücresinde ay, E2 hücresinde gün farkını bulacağız.

    Son F2 hücresinde ise tüm bu işlemlerin gerçekleştirildiği förmülü tek bir formül altında toplayın yaş hesabını gün, ay, yıl bazında tek hücrede göstereceğiz.

    A2 ve B2 hücrelerine geçerli tarihleri girdikten sonra C2 hücresinde aradan geçen yılı bulmak için aşağıdaki formülü girelim. Böylece iki tarih arasında kalan yıl farkını bulalım.

    Kod:
    =YIL(B2)-YIL(A2)-EĞER(YADA(AY(B2)<AY(A2);VE(AY(B2)=AY(A2);GÜN(B2)<GÜN(A2)));1;0)&" yıl"
    İki tarih arasında yıl farkından arta kalan ayları bulmak için D2 hücresine aşağıdaki formülü giriyoruz.

    Kod:
    =AY(B2)-AY(A2)+EĞER(VE(AY(B2)<=AY(A2);GÜN(B2)<GÜN(A2));11;EĞER(VE(AY(B2)<AY(A2);GÜN(B2) >=GÜN(A2));12;EĞER(VE(AY(B2)>AY(A2);GÜN(B2)<GÜN(A2));-1)))&" ay"
    E2 hücresine ise yıl ve ay farkından arta kalan gün sayısını bulmak için alttaki formülü giriyoruz.

    Kod:
    =B2-TARİH(YIL(B2);AY(B2)-EĞER(GÜN(B2)<GÜN(A2);1;0);GÜN(A2))&" gün"
    Böylece ayrı hücrelerde iki tarih arasındaki farkı gün, ay ve yıl bazında bulduk. Şimdi ise tüm bu işlemleri bir hücrede göstermek için F2 hücresine aşağıdaki formülü girin.

    Kod:
    =YIL(B2)-YIL(A2)-EĞER(YADA(AY(B2)<AY(A2);VE(AY(B2)=AY(A2);GÜN(B2)<GÜN(A2)));1;0)&" yıl, "&AY(B2)-AY(A2)+EĞER(VE(AY(B2)<=AY(A2);GÜN(B2)<GÜN(A2));11;EĞER(VE(AY(B2)<AY(A2);GÜN(B2) >=GÜN(A2));12;EĞER(VE(AY(B2)>AY(A2);GÜN(B2)<GÜN(A2));-1)))&" ay, "&B2-TARİH(YIL(B2);AY(B2)-EĞER(GÜN(B2)<GÜN(A2);1;0);GÜN(A2))&" gün"
    Bu çalışma ile kolaylıkla gün, ay, yıl bazında iki tarih arasındaki farkı hesaplayabilirsiniz. Resimde görüldüğü gibi diğer hücrelerde de bu işlemi yapmak için formül olan hücreleri seçip alta doğru sürüklemek yeterli.

    Bu çalışmanın olduğu örnek excel dosyasını aşağıdaki linkten indirebilirsiniz.

    [ [Linkleri görebilmek için ÜYE olmalısınız!..] ]

Sayfayı Paylaş